Back in 2015 Nils posted a DfAbout.pkg that could display the compile date by extracting it from the.exe. Unfortunately this didn't work for me in DF19.1 and the problem seemed to be that it's in a different place in every .exe.
The following replacement for the GetCompileDate method works in 19.0 (and presumably earlier versions) and in 19.1:
    Function GetCompileDate Returns Date
        Integer iSize iLength iChannel iPos iDateFormat
        String  sAppFileName sAppName sData sCompileDate
        Date    dCompileDate

        // Get the full path to the current running executable
        Get GetApplicationFileName of ghoApplication   to sAppFileName
        // Get the name of the current running executable
        Get GetApplicationName of ghoApplication to sAppName
        // Read the current file past where where the data we're interesting in is likely to be.
        // It follows the embedded program name
        Get Seq_Open_Input_Channel ("binary:" * sAppFileName) to iChannel
        Get_Argument_Size to iSize
        Set_Argument_Size 3000000
        Read_Block channel iChannel sData 3000000   // This must be big enough to reach the compile date location
        Move (Pos(sAppName,sData)) to iPos
        If (iPos > 0) Begin
            // The compile date is 10 characters long and starts 3 characters after the program name
            Move (Mid(sData,10,iPos + Length(sAppName)+ 3)) to sCompileDate  // In US format

            // If the current date format is non US, we need to temporary
            // change the format and then move the string to the date variable.
            Get_Attribute DF_DATE_FORMAT        to iDateFormat
            Set_Attribute DF_DATE_FORMAT        to DF_DATE_USA
            Move (Date(sCompileDate))           to dCompileDate
            Set_Attribute DF_DATE_FORMAT        to iDateFormat // Reset date format
        Else Error DFERR_PROGRAM "Compile Date location in .exe not found"

        Send Seq_Close_Channel iChannel
        Set_Argument_Size iSize

        Function_Return dCompileDate

    End_Function    // GetCompileDate
The error is triggered if the Read_Block command hasn't read enough to find the program name, and an Invalid Date error will be triggered if it doesn't also read far enough to get the complete date.